#version 3.7;

global_settings { assumed_gamma 1.0 }

#include  "colors.inc"
#include  "textures.inc"
#include  "metals.inc"
#include  "trucs.inc"

light_source { <80, 30, 51> color Gray60 }
light_source { <80, 180, -151> color Gray30 }
light_source { <-80, 280, -151> color Gray30 }

sky_sphere {
  pigment {
    gradient y
      color_map {
        [ 0.5  color CornflowerBlue ]
        [ 1.0  color MidnightBlue ]
        }
    scale 0.05
    translate -1
    }
  // emission rgb <0.8,0.8,1>
  }

#local scalY = 1.700 +
		sin(radians(clock)) + 0.3*sin(radians(clock*5));
sphere	{ <0, 0, 0>, 1.1 scale <1, scalY, 1>
	  pigment { rgb <1, 0, 0.3> }
	normal { agate 1.00 scale 0.4 }
	translate <0, 1.65, 0> 
	}

#declare Pilier = object
{
cylinder { <0, -0.3, 0>, <0, 4.3, 0>, 0.06 }
texture { T_Copper_3A }
}

#for (foo, 0, 360, 15)
  #local px = 4*sin(radians(foo));
  #local pz = 4*cos(radians(foo));
  object { Pilier translate <px, 0, pz> }
#end

#declare BouleMiroir = object
{
sphere { <0, 0, 0>, 0.3  
	texture {
		pigment { color <0.55, 0.55, 0.77>  }
		finish { phong 0.03 reflection 0.97 }
		}
	}
}

#for (foo, 0, 170, 17)
	#local phy = foo;
	#local px = 3*sin(radians(clock+phy));
	#local pz = 3*cos(radians(clock+phy));
	object { BouleMiroir translate < px, 0.5+abs(pz),  pz> }
#end

object { Sol }
// object { Repere }

camera	{
	location <7, 3, -9>
	look_at <0.1, 1.8, 0.11>
	angle 49
	}