/*
 *
 */
#declare H_stele = 3.25;		// hauteur du fond
#declare E_stele = 0.55;		// epaisseur
#declare L_stele = 2.35;		// demi-largeur

#declare Gravure_Stele = object
{
#local Epp = 0.04;
union	{
        text { ttf "FreeSansBold.ttf" , "HALT AND CATCH FIRE", Epp, 0
                        translate <0.0, 0.95, 0> }
        text { ttf "FreeSansBold.ttf", "... LIKE A WARRIOR !", Epp, 0
                        translate <0.5, 0.05, 0> }
	}
scale <-0.29, 0.48, 0.55>
translate <1.57, 1.98, 0>
}

#declare Stele_fond = object
{
box { <-L_stele, 0, 0.01>, <L_stele, H_stele, E_stele> }
texture { T_Grnt10 scale 0.95 }
}

#declare Stele_fond_gravure = object
{
difference	{
	object { Stele_fond }
	object { Gravure_Stele  translate (E_stele-0.004)*z }
	}
}

/*		---			*/
#declare Stele_base = object
{
#local Dx = 0.55;
#local Zd = E_stele+1.40;
#local H2 = H_trottoir / 2;
difference {
	box { <-(L_stele+Dx), 0, 0>, <L_stele+Dx, H_trottoir, Zd> }
	cylinder { <-(L_stele+Dx), H2, Zd>, <-(L_stele+Dx), 1, Zd>, 0.333 }
	cylinder { < (L_stele+Dx), H2, Zd>, < (L_stele+Dx), 1, Zd>, 0.333 }
	}

texture { T_Stone31 scale 0.21 }
}
/*		---			*/

#declare Stele_un_coin = object
{
#local HC = H_stele+0.12;
#local R_coin = 0.17;

merge {
	cylinder { <0, 0, 0>, <0, 0.40, 0>, R_coin*2 }
	cone { <0, 0.30, 0>, R_coin*2, <0, 0.48, 0>, R_coin }
	cylinder { <0, 0, 0>, <0, HC, 0>, R_coin }
	sphere { 0, R_coin scale <1, 0.666, 1> translate y*HC }
	}
}

#declare Stele_les_coins = object
{
union	{
	object { Stele_un_coin translate <-L_stele, 0, E_stele> }
	object { Stele_un_coin translate < L_stele, 0, E_stele> }
	}
texture { T_Grnt12 scale 1.50 }
}

/*		truc etrange */

#declare Stele_A_milieu = object
{
union	{
	#local HSA = 1.95;
	#local HSB = HSA - 0.45;

	box      { <-1.10, 0, -0.25>, <1.15, 0.10, 0.25> }
	cylinder { < 0, 0,  0>, <0, HSA, 0>, 0.09       }
	sphere   { 0, 0.09  scale <1, 4, 1> translate y*HSA }
	cylinder { <-0.80, 0,  0>, <0, HSB, 0>, 0.045       }
	cylinder { < 0.80, 0,  0>, <0, HSB, 0>, 0.045       }
	}

texture {
	pigment { color Gray90 }
	// finish { specular 0.80 }
	finish { LOL_FINISH }
	}
}

#declare Stele_A = object
{
union	{
	object { Stele_base 					}
	object { Stele_fond_gravure 				}
	object { Stele_les_coins 				}
	object { Stele_A_milieu translate <0, H_trottoir, 1.39> }
	}
}

/* ------------------- variant ------------------------- */

#declare Stele_B_milieu = object
{
union	{
	cylinder { <0, 0, 0>, <0, 0.45, 0>, 0.23 }
	cone { <0, 0.45, 0>, 0.23, <0, 0.55, 0>, 0.14 }
	cylinder { <0, 0, 0>, <0, 1.15, 0>, 0.14 }
	sphere { 0, 0.14 scale <1, 0.717, 1> translate y*1.15 }
	}
scale <1.15, 1, 0.95>
texture {
	pigment { color Turquoise }
	finish { phong PHONG emission 0.07 specular SPECULAR  }
	}
}

#declare Stele_B = object
{
union	{
	object { Stele_base 				}
	object { Stele_fond_gravure 			}
	object { Stele_les_coins 			}
	object { Stele_B_milieu translate  <-1.38, H_trottoir, 1.46> }
	object { Stele_B_milieu translate  < 1.38, H_trottoir, 1.46> }
	}
}